ビーカー・試験管の自動交換装置（作成方法・プログラムあり）

#include <A4988.h>
#include <Servo.h>

// ピン定義
const int MOTOR_STEPS = 200;
const int DIR = 9;
const int STEP = 10;
const int switchPin1 = 5;
const int switchPin2 = 4; // 新しいスイッチのピン番号
const int switchPin3 = 2; // 回転数切り替え用のスイッチ

const int servoPin = 3;
const int servoMin = 0;
const int servoMax = 180;

// 回転数定義
int numSteps = 64; // 初期値は64、スイッチで200に切り替え可能

float rpm = 15;
int microsteps = 10;

A4988 stepper(MOTOR_STEPS, DIR, STEP);
Servo servo;

int servoPos = 90;
const int servoStep = 2; // サーボモーターの回転速度調整（大きいほど速く回転）

void setup() {
  Serial.begin(9600);
  stepper.begin(rpm, microsteps);
  pinMode(switchPin1, INPUT_PULLUP);
  pinMode(switchPin2, INPUT_PULLUP);
  pinMode(switchPin3, INPUT_PULLUP); // 新しいスイッチ用のピン設定

  servo.attach(servoPin);
  servo.write(servoPos);
}

void loop() {
  // スイッチ3が押されたら回転数定義を切り替える
  if (digitalRead(switchPin3) == LOW) {
    if (numSteps == 64) {
      numSteps = 200;
      Serial.println("Switch 3 pressed, numSteps set to 200");
    } else {
      numSteps = 64;
      Serial.println("Switch 3 pressed, numSteps set to 64");
    }
    delay(500); // デバウンス処理
  }

  if (digitalRead(switchPin1) == LOW) {
    // サーボモーターをA→Bまでゆっくり回転
    Serial.println("Switch 1 pressed");
    rotateServo(servo, 180, 30); // A=180, B=30
  }

  if (digitalRead(switchPin2) == LOW) {
    Serial.println("Switch 2 pressed");
    rotateServoAndStepper(servo, stepper, 180, 30, numSteps); // A=180, B=30に変更
  }
}

void rotateServo(Servo &servo, int servoStart, int servoEnd) {
  Serial.println("Rotating servo from " + String(servoStart) + " to " + String(servoEnd));
  if (servoStart > servoEnd) {
    for (int pos = servoStart; pos >= servoEnd; pos -= servoStep) {
      servo.write(pos);
      delay(20);
    }
  } else {
    for (int pos = servoStart; pos <= servoEnd; pos += servoStep) {
      servo.write(pos);
      delay(20);
    }
  }
}

void rotateServoAndStepper(Servo &servo, A4988 &stepper, int servoStart, int servoEnd, int stepperSteps) {
  // サーボモーターをA→Bまでゆっくり回転
  Serial.println("Rotating servo and stepper");
  rotateServo(servo, servoStart, servoEnd);
  delay(2000);
  // ステッピングモーターを指定ステップ回転
  stepper.move(stepperSteps);

  // サーボモーターをB→Aまでゆっくり回転
  rotateServo(servo, servoEnd, servoStart);
}